lithium flowers bloom

import ddf.minim.signals.*;
import ddf.minim.*;
import ddf.minim.analysis.*;
import ddf.minim.effects.*;
import processing.serial.*;

Serial myPort;
boolean connected = false;

String activeTag = "Waiting...";
PFont f = createFont("Helvetica", 50);

Hashtable cards;
Minim minim;
AudioInput in;
AudioRecorder recorder;
AudioPlayer player;

String previousCard = "";
boolean playMode = false;
boolean autoPilot = true;

void setup()
{
    println("connecting...");
    myPort = new Serial(this, Serial.list()[0], 9600);
    myPort.clear();
    cards = new Hashtable();

    loadCards();

    minim = new Minim(this);
    in = minim.getLineIn(Minim.STEREO, 2048);

    size(800,600);
    background(0);
    fill(255);
    noStroke();
    textAlign(CENTER);
    textFont(f);
    text("WAITING",width / 2, height / 2);
}

void draw()
{
    background(0);
    if (!connected)
    {
        myPort.write('C');
    }
    else
    {
        text(activeTag,width / 2, height / 2);

        if (playMode)
        {
            text("PLAYING",width / 2, height / 2 + 90);
        }
        else
        {
            text("RECORDING",width / 2, height / 2 + 90);
        }
        if (recorder != null)
        {
            stroke(255);
            if (playMode)
            {
                if (player != null)
                {
                    for(int i = 0; i < player.left.size()-1; i++)
                    {
                        line(i, 50 + player.left.get(i)*50, i+1, 50 + player.left.get(i+1)*50);
                        line(i, 150 + player.right.get(i)*50, i+1, 150 + player.right.get(i+1)*50);
                    }
                }
            }
            else
            {
                for(int i = 0; i < in.bufferSize() - 1; i++)
                {
                    line(i, 50 + in.left.get(i)*50, i+1, 50 + in.left.get(i+1)*50);
                    line(i, 150 + in.right.get(i)*50, i+1, 150 + in.right.get(i+1)*50);
                }
            }  
        }
    }
}

void closePlayer()
{
    if (player != null && player.isPlaying())
    {
        try
        {
            player.close();
        }
        catch (Exception e)
        {

        }
    }
}

void closeRecorder()
{
    if (recorder != null/* && recorder.isRecording()*/)
    {
        try
        {
            recorder.endRecord();
            recorder.save();
        }
        catch(Exception e)
        {

        }
    }
}

void loadCards()
{
    cards.clear();
    String []lines = loadStrings("index.txt");
    if (lines == null)
    {
        return;
    }

    for (int i = 0; i < lines.length ; i++)
    {
        String card = trim(lines[i]);
        cards.put(card, true);
    }
}

void dumpCards()
{
    PrintWriter writer = createWriter("data/index.txt");

    for (Enumeration e = cards.keys() ; e.hasMoreElements() ;)
    {
        String card = e.nextElement().toString();
        writer.println(card);
    }

    writer.flush();
    writer.close();
}

void serialEvent(Serial port) {
    String myString = port.readStringUntil(' ');
    if (myString != null)
    {
        myString = trim(myString);
        if (myString.equals("connected"))
        {
            connected = true;
            println("connected~!");
        }
        else
        {
            if (myString.equals("0000000000"))
            {
                activeTag = "Disconnected";

                if (playMode && player != null)
                {
                    println(previousCard + ": Disconnect from playing");
                    closePlayer();
                }
                else
                {
                    println(previousCard + ": Disconnect from recording");
                    closeRecorder();
                }
                previousCard = "";

            }
            else
            {
                activeTag = myString;

                if (!cards.containsKey(activeTag))
                {
                    cards.put(activeTag,true);
                    dumpCards();
                    if (autoPilot)
                    {
                        closePlayer();
                        playMode = false; //auto switch to record      
                        println("Autopilot: switch to record mode");           
                    }
                }
                else //found
                {
                    if (autoPilot)
                    {
                        playMode = true; //auto switch to play 
                        closeRecorder();
                        println("Autopilot: switch to play mode");                     
                    }
                }

                if (playMode)
                {
                    if (cards.containsKey(activeTag))
                    {
                        println(activeTag + ": Start playing new file, disconnect from previous " + previousCard);

                        closePlayer();

                        println("loading " + activeTag + " to play");
                        player = minim.loadFile("data/" + activeTag + ".wav", 2048);
                        player.play();
                        player.loop();
                    }
                    else
                    {
                        println(activeTag + ": Not recorded yet");
                    }
                }
                else //record mode
                {
                    if (activeTag != previousCard)
                    {
                        println(activeTag + ": Start playing new file, disconnect from previous " + previousCard);
                        closePlayer();                     
                        closeRecorder();
                    }

                    recorder = minim.createRecorder(in, "data/" + activeTag + ".wav", true);
                    recorder.beginRecord();
                }

                previousCard = activeTag;
            }
        }
    }
}

void stop()
{
        in.close();

    closePlayer();
    closeRecorder();

    minim.stop();
    super.stop();
}

void keyPressed()
{
    if (key == ' ')
    {
        playMode = !playMode;

        if (playMode)
        {
            println("play mode");
        }
        else
        {
            println("record mode");
        }
    }

    if (key == 'a')
    {
        autoPilot = !autoPilot;

        if (autoPilot)
        {
            println("Autopilot: ON");
        }
        else
        {
            println("Autopilot: OFF");
        }
    }
}